Prvni ulozeni z chegewara githubu

libraries/Preferences/examples/Prefs2Struct/Prefs2Struct.ino

@@ -0,0 +1,43 @@
+/*
+This example shows how to use Preferences (nvs) to store a
+structure.  Note that the maximum size of a putBytes is 496K
+or 97% of the nvs partition size.  nvs has signifcant overhead,
+so should not be used for data that will change often.
+*/ 
+#include <Preferences.h>
+Preferences prefs;
+
+typedef struct {
+  uint8_t hour;
+  uint8_t minute;
+  uint8_t setting1;
+  uint8_t setting2;
+} schedule_t;
+
+void setup() {
+  Serial.begin(115200);
+  prefs.begin("schedule"); // use "schedule" namespace
+  uint8_t content[] = {9, 30, 235, 255, 20, 15, 0, 1}; // two entries
+  prefs.putBytes("schedule", content, sizeof(content));
+  size_t schLen = prefs.getBytesLength("schedule");
+  char buffer[schLen]; // prepare a buffer for the data
+  prefs.getBytes("schedule", buffer, schLen);
+  if (schLen % sizeof(schedule_t)) { // simple check that data fits
+    log_e("Data is not correct size!");
+    return;
+  }
+  schedule_t *schedule = (schedule_t *) buffer; // cast the bytes into a struct ptr
+  Serial.printf("%02d:%02d %d/%d\n", 
+    schedule[1].hour, schedule[1].minute,
+    schedule[1].setting1, schedule[1].setting2);
+  schedule[2] = {8, 30, 20, 21}; // add a third entry (unsafely)
+// force the struct array into a byte array
+  prefs.putBytes("schedule", schedule, 3*sizeof(schedule_t)); 
+  schLen = prefs.getBytesLength("schedule");
+  char buffer2[schLen];
+  prefs.getBytes("schedule", buffer2, schLen);
+  for (int x=0; x<schLen; x++) Serial.printf("%02X ", buffer[x]);
+  Serial.println(); 
+}
+
+void loop() {}

libraries/Preferences/examples/StartCounter/StartCounter.ino

@@ -0,0 +1,56 @@
+/*
+ ESP32 startup counter example with Preferences library.
+
+ This simple example demonstrates using the Preferences library to store how many times
+ the ESP32 module has booted. The Preferences library is a wrapper around the Non-volatile
+ storage on ESP32 processor.
+
+ created for arduino-esp32 09 Feb 2017
+ by Martin Sloup (Arcao)
+*/
+
+#include <Preferences.h>
+
+Preferences preferences;
+
+void setup() {
+  Serial.begin(115200);
+  Serial.println();
+
+  // Open Preferences with my-app namespace. Each application module, library, etc
+  // has to use a namespace name to prevent key name collisions. We will open storage in
+  // RW-mode (second parameter has to be false).
+  // Note: Namespace name is limited to 15 chars.
+  preferences.begin("my-app", false);
+
+  // Remove all preferences under the opened namespace
+  //preferences.clear();
+
+  // Or remove the counter key only
+  //preferences.remove("counter");
+
+  // Get the counter value, if the key does not exist, return a default value of 0
+  // Note: Key name is limited to 15 chars.
+  unsigned int counter = preferences.getUInt("counter", 0);
+
+  // Increase counter by 1
+  counter++;
+
+  // Print the counter to Serial Monitor
+  Serial.printf("Current counter value: %u\n", counter);
+
+  // Store the counter to the Preferences
+  preferences.putUInt("counter", counter);
+
+  // Close the Preferences
+  preferences.end();
+
+  // Wait 10 seconds
+  Serial.println("Restarting in 10 seconds...");
+  delay(10000);
+
+  // Restart ESP
+  ESP.restart();
+}
+
+void loop() {}